テーブルの列の指定方法を色々考えてみました。配列に入れてクラス使用

＜標準モジュール＞
Sub tableColumnArrayWithClass()
    
    ' クラスをインスタンス化
    Dim c As clsTableColumns
    Set c = New clsTableColumns
    
    Dim wb As Workbook
    Set wb = ThisWorkbook  ' 現在のブックを設定
    Dim ws As Worksheet
    Set ws = wb.Worksheets(1)  ' 一つ目のシートを設定
    
    ' クラスのTableプロパティにテーブルを設定
    Set c.Table = ws.ListObjects(1)  ' 一つ目のテーブルを設定
    
    ' クラスの各プロパティ（列インデックス）をデバッグ出力
    Debug.Print c.氏名, c.所属部署, c.担当地区, c.受注件数, c.受注額
    
    ' テーブルのデータのみを配列に入れる
    Dim tbl As Variant
    tbl = ws.Range("営業[#Data]")  ' テーブルのデータ部分のみを配列に格納
    ' Rangeの前に、wsを入れているのは、別ブックがアクティブになっているとエラーになるため。
    ' これにより、特定のワークシートを明示的に指定して参照している。

    Dim rw As Long
    ' 配列の行数分だけループを回す。UBound(tbl)は配列の最終行を取得。
    For rw = 1 To UBound(tbl)
        ' 「氏名」列の各行の値をデバッグ出力
        Debug.Print tbl(rw, c.氏名)
    Next rw
    
End Sub


＜クラスモジュール: clsTableColumns ＞
Private tbl As ListObject  ' テーブルオブジェクトを保持するためのプライベート変数

' TableプロパティのSetメソッド。テーブルオブジェクトを設定する
Public Property Set Table(ByVal argTbl As ListObject)
    Set tbl = argTbl
End Property

' 指定された列名に対応する列番号を取得するためのプライベート関数
Private Function getColumn(ByVal argName As String) As Long
    ' 列のインデックスを返す
    getColumn = tbl.ListColumns(argName).index
End Function

' 氏名プロパティのGetメソッド。列インデックスを返す
Public Property Get 氏名() As Long
    Static c As Long  ' キャッシュ用の静的変数
    If c <> 0 Then 氏名 = c: Exit Property  ' キャッシュが存在する場合、それを返す
    c = getColumn("氏名")  ' 列インデックスを取得してキャッシュに保存
    氏名 = c  ' 列インデックスを返す
End Property

Public Property Get 所属部署() As Long
    Static c As Long
    If c <> 0 Then 所属部署 = c: Exit Property
    c = getColumn("所属部署")
    所属部署 = c
End Property

Public Property Get 担当地区() As Long
    Static c As Long
    If c <> 0 Then 担当地区 = c: Exit Property
    c = getColumn("担当地区")
    担当地区 = c
End Property

Public Property Get 受注件数() As Long
    Static c As Long
    If c <> 0 Then 受注件数 = c: Exit Property
    c = getColumn("受注件数")
    受注件数 = c
End Property

Public Property Get 受注額() As Long
    Static c As Long
    If c <> 0 Then 受注額 = c: Exit Property
    c = getColumn("受注額")
    受注額 = c
End Property