二次元関数の行列変換を例に、配列を引数に配列を返す関数を紹介

' 配列の行列変換
Function TransposeArray(ByVal myArray As Variant) As Variant
    Dim x As Long, y As Long
    Dim maxX As Long, minX As Long
    Dim maxY As Long, minY As Long
    
    Dim tempArr As Variant
    
    '上限と下限を取得
    maxX = UBound(myArray, 1)
    minX = LBound(myArray, 1)
    maxY = UBound(myArray, 2)
    minY = LBound(myArray, 2)
    
    '一時的な配列を作成する
    ReDim tempArr(minY To maxY, minX To maxX)
    
    '配列の行列変換
    For x = minX To maxX
        For y = minY To maxY
            tempArr(y, x) = myArray(x, y)
        Next y
    Next x
    
    '出力配列
    TransposeArray = tempArr
    
End Function

Sub TestTransposeArray()
    Dim tempArr(1 To 3, 1 To 2) As Variant
    Dim outputArrApp As Variant
    Dim outputArrFun As Variant
    
    '配列の値を代入する
    tempArr(1, 1) = "Steve"
    tempArr(1, 2) = "Johnson"
    tempArr(2, 1) = "Ryan"
    tempArr(2, 2) = "Jon"
    tempArr(3, 1) = "Andrew"
    tempArr(3, 2) = "Scott"
    
    '独自の行列変換関数を呼び出す
    outputArrFun = TransposeArray(tempArr)
    'Excelで使用できる行列変換関数を使用
    outputArrApp = Application.WorksheetFunction.Transpose(tempArr)
    
    ' 二次元配列のどちらの配列も、２つ以上の場合は、どちらの関数を使用しても、同じ配列に変換される
End Sub

Sub TestTransposeArray1()
    'Dim tempArr(1 To 3, 1 To 2) As Variant
    Dim tempArr(1 To 3, 1 To 1) As Variant
    Dim outputArrApp As Variant
    Dim outputArrFun As Variant
    
    '配列の値を代入する
    tempArr(1, 1) = "Steve"
    'tempArr(1, 2) = "Johnson"
    tempArr(2, 1) = "Ryan"
    'tempArr(2, 2) = "Jon"
    tempArr(3, 1) = "Andrew"
    'tempArr(3, 2) = "Scott"
    
    '独自の行列変換関数を呼び出す
    outputArrFun = TransposeArray(tempArr)
    'Excelで使用できる行列変換関数を使用
    outputArrApp = Application.WorksheetFunction.Transpose(tempArr)
    
    ' 二次元配列の内、二つ目の配列を、1にした場合は、Excel関数では一次元配列になってしまう。
    ' 独自関数では、二次元配列のままで、行列が変換されている。
End Sub

Sub TestTransposeArray2()
    'Dim tempArr(1 To 3, 1 To 2) As Variant
    Dim tempArr(1 To 1, 1 To 2) As Variant
    Dim outputArrApp As Variant
    Dim outputArrFun As Variant
    
    '配列の値を代入する
    tempArr(1, 1) = "Steve"
    tempArr(1, 2) = "Johnson"
    'tempArr(2, 1) = "Ryan"
    'tempArr(2, 2) = "Jon"
    'tempArr(3, 1) = "Andrew"
    'tempArr(3, 2) = "Scott"
    
    '独自の行列変換関数を呼び出す
    outputArrFun = TransposeArray(tempArr)
    'Excelで使用できる行列変換関数を使用
    outputArrApp = Application.WorksheetFunction.Transpose(tempArr)
    
    ' 二次元配列の内、一つ目の配列を、1にした場合は、
    ' どちらの関数を使用しても、同じ配列に変換される
End Sub