複数の文字列を含みかつ複数の文字列を含まない、かどうかを判断する関数

'**************************************************************
'* 複数の文字列を含みかつ複数の文字列を含まない、かどうかを判断
'* str: チェック対象の文字列
'* searchStrings: str に全て含まれているべき文字列の配列
'* excludeStrings: str に含まれていてはならない文字列の配列
'* 戻り値：trueで該当、falseで非該当
Function MultipleIncludesAndExcludes(ByVal str As String, _
            ByRef searchStrings() As String, _
            ByRef excludeStrings() As String) As Boolean

    ' 判定フラグを初期化（初期値は該当するものとしてTrue）
    Dim isMatche As Boolean
    isMatche = True

    ' ループ変数の宣言
    Dim i As Long
    
    ' 検索文字列が全て含まれているか確認
    For i = LBound(searchStrings) To UBound(searchStrings)
        ' 各検索文字列がstrに含まれていない場合、判定フラグをFalseに設定
        If InStr(str, searchStrings(i)) = 0 Then
            isMatche = False
        End If
    Next i

    ' 除外文字列が含まれていないか確認
    For i = LBound(excludeStrings) To UBound(excludeStrings)
        ' 各除外文字列がstrに含まれている場合、判定フラグをFalseに設定
        If InStr(str, excludeStrings(i)) > 0 And excludeStrings(i) <> "" Then
            isMatche = False
        End If
    Next i

    ' 判定フラグの値を関数の戻り値として返す
    MultipleIncludesAndExcludes = isMatche
End Function

Private Sub TestMultipleIncludesAndExcludes()
    Dim searchStrings(1) As String
    Dim excludeStrings(1) As String
    Dim testString As String
    Dim result As Boolean

    ' 検索文字列の配列を設定
    searchStrings(0) = "test"
    searchStrings(1) = "2024"
    
    ' 除外文字列の配列を設定
    excludeStrings(0) = "draft"
    excludeStrings(1) = "backup"
    
    ' チェックする文字列を設定
    testString = "test_document_2024.xlsx"
    ' 関数を呼び出して結果を取得
    result = MultipleIncludesAndExcludes(testString, searchStrings, excludeStrings)
    Debug.Print result      ' True
    
    ' チェックする文字列を設定
    testString = "test_document_2023.xlsx"
    ' 関数を呼び出して結果を取得
    result = MultipleIncludesAndExcludes(testString, searchStrings, excludeStrings)
    Debug.Print result      ' False。「2024」が含まれていないので、False
    
    ' チェックする文字列を設定
    testString = "test_draft_2024.xlsx"
    ' 関数を呼び出して結果を取得
    result = MultipleIncludesAndExcludes(testString, searchStrings, excludeStrings)
    Debug.Print result      ' False。「draft」が含まれているので、False
    
End Sub