QueryTableオブジェクトを使用して、高速にCSVをシートに取り込む

'*******************************
'* QueryTableオブジェクトを使用して、高速にCSVをシートに取り込む。20240514
'* filePath：ファイルパス名
'* rng：取り込むシートの先頭のRange
'* charSet：文字コード。Shift_JIS, UTF-8, Unicode, JIS, UTF-7, euc-jp に対応。デフォルト：Shift_JIS
'* delimiter：区切り文字。Comma, Tab に対応。デフォルト：Comma
'* https://qiita.com/tiechel/items/40dd7cd7cf632bd6f41e
Sub csv_to_sheet_QueryTables(ByVal filePath As String, ByVal rng As Range, _
        Optional ByVal charSet As String = "Shift_JIS", _
        Optional ByVal delimiter As String = "Comma")
    
    On Error GoTo ErrorHandler
    Application.ScreenUpdating = False
    
    '文字列の書式用に配列を作成
    Dim Tcount(255) As Long
    Dim i As Long
    For i = 0 To 255                    ' 256列まで対応
        Tcount(i) = xlTextFormat        ' 文字列の書式を指定
    Next

    ' ワークシートオブジェクトを作成し、データをクリア
    Dim ws As Worksheet
    Set ws = rng.Parent
    ws.Cells.Clear

    ' QueryTablesオブジェクトを使用してcsvファイルを読み込む
    With ws.QueryTables.Add(Connection:="text;" & filePath, Destination:=rng)
        ' 文字コードの指定
        If charSet = "Shift_JIS" Then
            .TextFilePlatform = 932 'SHIFTJIS
        Else
            .TextFilePlatform = 65001 'UTF-8
        End If
        
        .AdjustColumnWidth = False '列の幅を自動計算しない
        
        ' 区切り文字を指定
        If delimiter = "Comma" Then
            .TextFileCommaDelimiter = True 'コンマ区切り
        Else
            .TextFileTabDelimiter = True
        End If
        
        ' 項目の型を指定
        .TextFileColumnDataTypes = Array(Tcount)  ' 全ての項目を文字列にする
        
        .Refresh BackgroundQuery:=False ' シートにデータを出力
        
        .Delete     ' QueryTablesオブジェクトを削除
    End With

    ws.Activate     ' ワークシートをアクティブにする

GoTo Finally:
ErrorHandler:
    MsgBox "エラーが発生しました" & vbCrLf & Err.Description & "(" & Err.Number & ")", vbExclamation
Finally:
    Application.ScreenUpdating = True

End Sub

Sub csv_to_sheet_QueryTables(ByVal filePath As String, ByVal rng As Range, _
        Optional ByVal charSet As String = "Shift_JIS", _
        Optional ByVal delimiter As String = "Comma")
    
    On Error GoTo ErrorHandler
    Application.ScreenUpdating = False

    '文字列の書式用に配列を作成
    Dim Tcount(255) As Long
    Dim i As Long
    For i = 0 To 255                    ' 256列まで対応
        Tcount(i) = xlTextFormat        ' 文字列の書式を指定
    Next

    ' ワークシートオブジェクトを作成し、データをクリア
    Dim ws As Worksheet
    Set ws = rng.Parent
    ws.Cells.Clear

    ' QueryTablesオブジェクトを使用してcsvファイルを読み込む
    With ws.QueryTables.Add(Connection:="text;" & filePath, Destination:=rng)
        ' 文字コードの指定
        If charSet = "Shift_JIS" Then
            .TextFilePlatform = 932 'SHIFTJIS
        Else
            .TextFilePlatform = 65001 'UTF-8
        End If
        
        .AdjustColumnWidth = False '列の幅を自動計算しない
        
        ' 区切り文字を指定
        If delimiter = "Comma" Then
            .TextFileCommaDelimiter = True 'コンマ区切り
        Else
            .TextFileTabDelimiter = True 'タブ区切り
        End If
        
        ' 項目の型を指定
        .TextFileColumnDataTypes = Array(Tcount)  ' 全ての項目を文字列にする
        
        .Refresh BackgroundQuery:=False ' シートにデータを出力
        
        .Delete     ' QueryTablesオブジェクトを削除
    End With

    ws.Activate     ' ワークシートをアクティブにする

GoTo Finally:
ErrorHandler:
    MsgBox "エラーが発生しました" & vbCrLf & Err.Description & "(" & Err.Number & ")", vbExclamation
Finally:
    Application.ScreenUpdating = True

End Sub

' ファイル名・文字コード・区切り文字を指定して、csvをシートに取り込む
Sub 使用例()
    ' ファイルパス名
    Dim filePath As String
    filePath = "H:\temp\sample5.csv"
    
    Dim rng As Range
    Set rng = ThisWorkbook.Worksheets("Sheet1").Range("A1")
    ' 文字コード
    Dim charSet As String
    charSet = "Shift_JIS"
    ' 区切り文字
    Dim delimiter As String
    delimiter = "Comma"
    
    ' QueryTableオブジェクトを使用して、高速にCSVをシートに取り込む
    Call csv_to_sheet_QueryTables(filePath, rng, charSet, delimiter)
End Sub